Hàm IF trong Excel: 2 điều kiện, 3 điều kiện và nhiều điều kiện

Hàm IF trong Excel là 1 trong những hàm quan trọng và được sử dụng thường xuyên khi bạn làm việc trên Excel. Trong bài viết này, Gitiho sẽ hướng dẫn cách sử dụng hàm IF cơ bản và hàm IF nhiều điều kiện với AND, OR, hàm IF lồng nhau và hơn thế nữa. Hãy cùng khám phá ngay nào!

Xem thêm: Top khóa học tin học văn phòng hay nhất tại Gitiho

Cách dùng hàm IF trong Excel

Hàm IF là một hàm Excel có tác dụng biện luận một mệnh đề logic để lấy kết quả tương ứng theo từng trường hợp Đúng/Sai củamệnh đề đó.

Cú pháp của hàm là:

=IF(logical_test, value_if_true, [value_if_false])

Trong đó bao gồm 3 thành phần là:

logical_test: Mệnh đề logic dùng để kiểm tra
value_if_true: Giá trị nhận được khi mệnh đề đúng (TRUE)
value_if_false: (không bắt buộc phải nhập) Giá trị nhận được khi mệnh đề sai

Kết quả trả về của hàm này là giá trị tương ứng với từng trường hợp mệnh đề Đúng hay Sai. Nếu không nhập tham số value_if_false mà kết quả mệnh đề logic là FALSE thì nhận chữ FALSE.

Lưu ý: Nếu không nhập tham số logical_test thì sẽ luôn nhận kết quả theo giá trị value_if_false.

Ví dụ 1 về hàm IF:

Cho mệnh đề: “Nếu ngày mai là chủ nhật thì “Nghỉ”, không phải thì “Đi học”.

Khi được triển khai vào hàm IF thì chúng ta có như sau:

logical_test: Ngày mai là chủ nhật. Đây là một câu mệnh đề logic, chúng ta sử dụng hàm để xác định thứ trong tuần và ngày nào như sau:

Ngày mai: TODAY() + 1
Thứ của ngày mai: WEEKDAY(TODAY() + 1)
Chủ nhật: 1 (hàm WEEKDAY) viết như trên cho kết quả bằng 1 được hiểu là chủ nhật

Công thức hoàn chỉnh cho ví dụ này là:

=IF(WEEKDAY(TODAY()+1,"Nghỉ","Đi học")

Ví dụ áp dụng hàm IF xác định ngày nghỉ và ngày đi học — Ví dụ áp dụng hàm IF 2 điều kiện xác định ngày nghỉ và ngày đi học

Qua ví dụ trên có thể thấy điều gây khó khăn nhất khi sử dụng hàm IF trong Excel đó là làm sao để diễn tả được một yêu cầu thành mệnh đề logic để chuyển thành công thức. Bây giờ hãy cũng đến với một bài tập Excel thực tế của chúng mình để làm quen với thao tác này nhé.

Ví dụ 2 về hàm IF cơ bản

Cho bảng dữ liệu về danh sách cửa hàng như sau:

Ví dụ về cách dùng hàm If để xếp loại cửa hàng theo doanh số

Yêu cầu:
Xác định kết quả cột xếp loại vùng F3:F12 biết:
Nếu Doanh số đạt từ 300 trở lên (lớn hơn hoặc bằng) thì xếp loại là “Đạt”.
Còn lại là “Không đạt”

Cách thực hiện như sau:

Bước 1: Phân tích mệnh đề logic:

logical_test: Doanh số >= 300.
value_if_true: “Đạt”
value_if_false: “Không đạt"

Bước 2: Viết công thức hoàn thiện vào ô F3:

= IF (E3>=300, "Đạt", "Không đạt")

Lưu ý khi nhập công thức hàm IF:

Nhập dấu bằng rồi nhập chữ I. Khi Excel đưa ra bảng gợi ý hàm thì dùng phím mũi tên di chuyển đến vị trị của hàm IF => bấm phím Tab để chọn hàm IF. Cách làm này sẽ tránh được việc chữ IF bị chuyển thành chữ “Ì” vì các bạn đang dùng bộ gõ tiếng Việt.
Nhập các thành phần của hàm IF. Nếu value_if_true và value_if_false của bạn là dạng chữ thì bạn phải đặt nó trong dấu nháy kép nhé.

Lưu ý khi nhập công thức hàm IF

Kết quả chúng ta có được sau bước này sẽ là:

Kết quả sau khi dùng IF để xếp loại cửa hàng

Bước 3: Filldown công thức

Cách copy công thức xuống các ô dưới thì không có gì khó khăn. Các bạn chỉ cần chọn vào ô đang chứa công thức sau đó nháy đúp chuột vào ô vuông màu xanh ở góc dưới bên phải của nó. Thao tác này sẽ làm cho công thức được sao chép đến dòng cuối của vùng chứa dữ liệu.

Sao chép công thức IF xuống các ô phía dưới

Có một cách sao chép công thức khác các bạn cũng có thể sử dụng là chọn toàn bộ vùng muốn áp dụng công thức rồi bấm Ctrl + D.

Cách sử dụng hàm IF nhiều điều kiện trong Excel

Đối với những dữ liệu Excel lớn, và yêu cầu bạn cần lọc ra những giá trị thỏa mãn nhiều điều kiện khác nhau, bạn sẽ cần kết hợp hàm IF với một số hàm cơ bản khác để có thể áp dụng được đồng thời nhiều điều kiện.

Dưới đây là một số hàm phổ biến nhất hay được sử dụng kết hợp với công thức hàm IF có điều kiện:

Hàm AND: Nếu điều kiện kiểm tra chứa hàm AND, Microsoft Excel sẽ trả về TRUE (Đúng) nếu tất cả các điều kiện được đáp ứng; nếu không sẽ trả về FALSE (Sai).Hàm OR: Trong trường hợp sử dụng hàm OR trong kiểm tra, Excel sẽ trả về TRUE nếu bất kỳ điều kiện nào được đáp ứng; nếu khác sẽ trả về FALSE (Sai).

Để minh họa rõ hơn, chúng ta hãy xem xét một vài ví dụ sau:

Kết hợp hàm IF với hàm AND trong Excel

Giả sử, bạn có một bảng với kết quả của hai điểm thi. Điểm số đầu tiên, được lưu trữ trong cột A, phải bằng hoặc lớn hơn 20. Điểm thứ hai, được liệt kê trong cột B, phải bằng hoặc vượt quá 30.
Chỉ khi đáp ứng cả hai điều kiện trên, học sinh mới vượt qua kỳ thi.

Cách dễ nhất để tạo một công thức thích hợp là viết ra điều kiện trước, sau đó kết hợp nó vào đối số kiểm tra hàm nhiều điều kiện trong Excel của bạn:

Công thức kết hợp hàm IF và AND:

=IF((AND(B2>=20;C2>=30));"Đậu";"Trượt")

Trong công thức trên, Excel trả về “Đậu” nếu giá trị trong cột C> = 20 và giá trị trong cột D> = 30. Nếu khác, công thức IF nhiều điều kiện sẽ trả về “Trượt”, như ví dụ trong ảnh dưới đây.

Kết quả sử dụng hàm if(and nhiều điều kiện) để xác định đậu, trượt trong kỳ thi

Ngoài 2 điều kiện, bạn có thể kết hợp hàm IF AND nhiều điều kiện hơn nữa tùy nhu cầu của bạn.

Kết hợp hàm IF OR nhiều điều kiện trong Excel

Bạn sử dụng kết hợp các hàm IF và hàm OR theo cách tương tự như với hàm AND ở trên. Khác biệt so là Excel sẽ trả về TRUE (Đúng) nếu ít nhất một trong các điều kiện được chỉ định được đáp ứng.

Vì vậy, công thức ở trên sẽ được sửa đổi theo cách sau:

=IF((OR(B2>=20; C2>=30));"Đậu";"Trượt")

Cột D sẽ trả về giá trị “Đậu” nếu điểm thứ nhất bằng hoặc lớn hơn 20 hoặc điểm thứ hai bằng hoặc lớn hơn 30.

Ví dụ dùng hàm IF kết hợp với hàm OR để xác định đậu, trượt

Sử dụng hàm IF kết hợp với hàm AND và OR trong Excel

Trong trường hợp bạn phải đánh giá dữ liệu của mình dựa trên nhiều điều kiện, bạn nên sử dụng kết hợp cả hai hàm AND và OR cùng một lúc.

Trong bảng trên, giả sử bạn có các tiêu chí sau để đánh giá điều kiện đạt của học sinh:
Điều kiện 1: cột B> = 20 và cột C> = 25Điều kiện 2: cột B> = 15 và cột C> = 20

Nếu một trong các điều kiện trên được đáp ứng thì bạn đó được coi là đã vượt qua, nếu không thì trượt.

Công thức đơn giản như sau:

OR(AND(B2>=20;C2>=25);AND(B2>=15;C2>=20)

Cuối cùng, sử dụng hàm OR ở trên làm điều kiện kiểm tra logic trong hàm IF nhiều điều kiện và cung cấp các đối số TRUE (Đúng) và FALSE (Sai). Kết quả là bạn sẽ nhận được công thức hàm IF trong Excel sau với nhiều điều kiện AND/OR:

Hàm IF kết hợp đồng thời cả hàm AND và OR để xác định đậu, trượt

=IF(OR(AND(B2>=20;C2>=25);AND(B2>=15;C2>=20));"Đậu";"Trượt")

Đương nhiên, bạn không bị giới hạn khi chỉ sử dụng với hai hàm là AND/OR trong các công thức hàm IF có điều kiện, miễn là:

Trong Excel 2016, 2013, 2010 và 2007, công thức không bao gồm quá 255 đối số và tổng độ dài của công thức không vượt quá 8.192 ký tự.
Trong Excel 2003 trở xuống, có thể sử dụng tối đa 30 đối số và tổng độ dài công thức không vượt quá 1.024 ký tự.

Cách dùng hàm IF lồng nhau

Nếu cần tạo các kiểm tra logic phức tạp hơn cho dữ liệu của mình, bạn có thể bao gồm các câu lệnh hàm IF trong Excel bổ sung cho các đối số TRUE (Đúng) và FALSE (Sai).

Hàm IF lồng nhau này đặc biệt hữu ích nếu bạn muốn công thức của mình trả về 3 hoặc nhiều kết quả khác nhau.

Ví dụ:

Bạn không chỉ muốn đủ điều kiện để đạt kết quả là Đậu/Trượt, mà xác định tổng điểm là “Tốt”, “Đạt yêu cầu” và “Kém “. Ví dụ:
Tốt: 60 trở lên (> = 60)
Đạt yêu cầu: từ 40 đến 60 (> 40 đến <60)
Kém: 40 hoặc ít hơn (<= 40)

Để bắt đầu, cần chèn thêm một cột tổng số điểm cột (D) của hai cột B và C với công thức tính tổng các số trong cột B và C:

=B2+C2

Ví dụ về hàm IF lồng nhau để xác định đạt yêu cầu và không đạt yêu cầu

Bây giờ chỉ cần viết một hàm IF lồng nhau dựa trên các điều kiện trên. Lúc này hàm IF có 3 điều kiện sẽ có dạng như sau:

=IF(D2>=60;"Tốt";IF(D2>40;"Đạt yêu cầu";"Kém"))

Như bạn thấy, chỉ cần áp dụng hàm IF nhiều điều kiện một lần là đủ trong trường hợp này. Đương nhiên, bạn có thể lồng thêm nhiều vế hàm IF trong Excel hơn nếu bạn muốn. Ví dụ:

=IF(D2>=70;”Xuất sắc”;IF(D2>=60;”Tốt”;IF(D2>40;”Đạt yêu cầu”;”Kém”)))

Công thức trên thêm một điều kiện nữa đó là tổng số điểm 70 và nhiều hơn nữa đủ điều kiện là “Xuất sắc”. Xem hình minh họa bên dưới:

Kết quả khi dùng nhiều hàm IF lồng nhau trong Excel

Sử dụng hàm IF với các hàm SUM, AVERAGE, MIN và MAX

Kết hợp hàm IF với hàm SUM

Ở ví dụ trên, để biết tổng số điểm của mỗi học sinh, chúng ta đã thêm một cột mới (D) để tính tổng cột B và C.

Nhưng nếu bảng của bạn có cấu trúc được xác định trước mà không cho phép bất kỳ sửa đổi nào? Trong trường hợp này, thay vì thêm cột trợ giúp, bạn có thể thêm giá trị trực tiếp vào công thức hàm IF của mình. Công thức như sau:

=IF((B2+C2)>=60;"Tốt";IF((B2+C2)=>40;"Đạt yêu cầu";"Kém"))

Ví dụ về hàm IF lồng nhau kết hợp với phép tính tổng

Nhưng nếu bảng của bạn chứa nhiều điểm ở nhiều cột khác nhau thì sao? Lúc này công thức hàm IF sẽ rất dài và dễ gây dối. Một cách khác là nhúng hàm SUM trong bài kiểm tra logic của hàm IF, lúc này công thức trên sẽ sửa thành:

=IF(SUM(B2:F2)>=120;"Tốt";IF(SUM(B2:F2)>=90;"Đạt yêu cầu";"Kém"))

Ví dụ về cách dùng hàm IF kết hợp với hàm SUM trong Excel

Kết hợp hàm IF và hàm AVERAGE trong Excel

=IF(AVERAGE(B2:F2)>=30;"Tốt";IF(AVERAGE(B2:F2)>=25;"Đạt yêu cầu";"Kém"))

Kết quả trả về là:

“Tốt” nếu điểm trung bình trong các cột B2 đến F2 bằng hoặc lớn hơn 30,

“Đạt yêu cầu” nếu điểm trung bình nằm trong khoảng từ 29 đến 25

“Kém” nếu dưới 25.

Sử dụng hàm IF và MAX/MIN

Để tìm điểm cao nhất và thấp nhất, bạn có thể sử dụng kết hợp với các hàm MAX và MIN tương ứng. Giả sử rằng cột F là cột tổng điểm, cách làm sẽ như sau:

MAX:

=IF(F2=MAX($F$2:$F$6);"Tốt nhất";””)

MIN:

=IF(F3=MIN($F$2:$F$6);"Kém nhất";””)

Nếu bạn muốn có cả kết quả MIN và MAX trong cùng một cột, có thể lồng một trong các công thức hàm IF trên vào các hàm khác, ví dụ:

=IF(F2=MAX($F$2:$F$10);"Tốt nhất";IF(F2=MIN($F$2:$F$10);"Kém nhất";""))

Kết quả cách dùng hàm IF kết hợp với hàm MAX trong Excel

Kết quả cách dùng hàm IF kết hợp với hàm Min trong Excel

Theo cách tương tự, bạn có thể sử dụng hàm IF có điều kiện với các hàm bảng tính tùy chỉnh của mình. Ngoài ra, Excel còn cung cấp một số công thức hàm IF trong Excel đặc biệt để phân tích và tính toán dữ liệu dựa trên các điều kiện khác nhau.

Ví dụ:

Để đếm số lần xuất hiện của một văn bản hoặc giá trị số dựa trên một hoặc nhiều điều kiện, bạn có thể sử dụng lần lượt: hàm COUNTIF và COUNTIFS.
Để tìm ra tổng các giá trị dựa trên (các) điều kiện được chỉ định, hãy sử dụng: hàm Hàm SUMIF hoặc SUMIFS.
Để tính trung bình theo các tiêu chí nhất định, sử dụng: Hàm AVERAGEIF hoặc AVERAGEIFS.

Sử dụng hàm IF với các hàm ISNUMBER và ISTEXT

Đây là ví dụ về hàm IF lồng nhau trả về “Văn bản” nếu ô B1 chứa bất kỳ giá trị văn bản nào, “Số” nếu B1 chứa giá trị số và “Trống” nếu B1 trống.

=IF(ISTEXT(B1);"Văn bản";IF(ISNUMBER(B1);"Số";IF(ISBLANK(B1);"Trống";"")))

Ghi chú: Công thức trên hiển thị kết quả là “Số” cho các giá trị số và ngày. Điều này là do Microsoft Excel lưu trữ ngày dưới dạng số, bắt đầu từ ngày 1 tháng 1 năm 1900, tương đương với 1.

Kết hợp hàm ISNUMBER và ISTEXT để xác định dữ liệu

Tổng kết

Trên đây là bài viết giới thiệu với bạn đọc cách dùng hàm IF trong Excel và hàm IF nhiều điều kiện kết hợp với các hàm thông dụng khác như AND, OR, MAX/MIN, AVERAGE qua các ví dụ trực quan, rất dễ hiểu.

Gitiho chúc các bạn thành công!